Programming Languages Suite/ProgLangD.iso/Borland Visual dBASE Professiona v7.0/DATA1.CAB/Sample_dBASE/Fleet/GenWizard.wfm

Text File | 1997-11-20 | 43KB | 1,575 lines

//--------------------------------------------------------------
//
//  GenWizard.wfm --  Schedule Generation Wizard
//
//  This form uses a common wizard interface to generate
//  airline schedules. Each step of the wizard is defined
//  as a seperate page on the form. The wizard uses
//  templates as a basis for generating new schedule data.
//  As users step through the wizard, they can select,
//  modify and create new templates.
//
//  Dependencies: GENWIZARD.DBF
//
//  Visual dBASE Samples Group
//
//  $Revision:   1.17  $
//
//  Copyright (c) 1997, Borland International, Inc.
//  All rights reserved.
//
//---------------------------------------------------------------
#DEFINE ALIASFLEET
SET TALK OFF
** END HEADER -- do not remove this line
//
// Generated on 10/23/97
//
parameter bModal
local f
f = new genwizardForm()
if (bModal)
   f.mdi = false // ensure not MDI
   f.readModal()
else
   f.open()
endif

class genwizardForm of FORM
   with (this)
      onClose = class::FORM_ONCLOSE
      open = class::FORM_OPEN
      readModal = class::FORM_READMODAL
      autoCenter = true
      scaleFontSize = 8
      scaleFontBold = false
      height = 16.4545
      left = 15
      top = 0.8636
      width = 82
      text = "Schedule Generation Wizard - Step 1 of 5"
      icon = "FILE fleet.ico"
   endwith


   this.DMCONNECT = new DATAMODREF()
   this.DMCONNECT.parent = this
   with (this.DMCONNECT)
      filename = "fconnect.dmd"
      dataModClass = "fconnectDataModule"
      share = 0
      active = true
      left = 50
      top = 0
   endwith


   this.AIRCRAFT1 = new QUERY()
   this.AIRCRAFT1.parent = this
   with (this.AIRCRAFT1)
      left = 76
      top = 4.5
      database = form.DMCONNECT.ref.dbfleet
      sql = 'SELECT * FROM "AIRCRAFT.DBF" aircaft'
      active = true
   endwith


   with (this.AIRCRAFT1.rowset)

      indexName = "AIRCRAFT ID"
   endwith


   this.FLIGHT1 = new QUERY()
   this.FLIGHT1.parent = this
   with (this.FLIGHT1)
      left = 76
      top = 6.5
      database = form.DMCONNECT.ref.dbfleet
      sql = 'SELECT * FROM "FLIGHT.DBF"'
      active = true
   endwith




   this.SCHEDULE1 = new QUERY()
   this.SCHEDULE1.parent = this
   with (this.SCHEDULE1)
      left = 76
      top = 0
      database = form.DMCONNECT.ref.dbfleet
      sql = 'SELECT * FROM "SCHEDULE.DBF"'
      active = true
   endwith




   this.RECTANGLE1 = new RECTANGLE(this)
   with (this.RECTANGLE1)
      left = 4
      top = 4.7273
      width = 75
      height = 2.3684
      metric = 0
      text = "Schedule"
      colorNormal = "WindowText/BtnFace"
      fontName = "MS Sans Serif"
      fontSize = 8
      pageno = 4
   endwith


   this.BOXCHANGES = new RECTANGLE(this)
   with (this.BOXCHANGES)
      left = 4
      top = 8
      width = 75
      height = 5.2105
      metric = 0
      text = "Template"
      colorNormal = "WindowText/BtnFace"
      fontName = "MS Sans Serif"
      fontSize = 8
      pageno = 4
   endwith


   this.BOXTEMPLATE = new RECTANGLE(this)
   with (this.BOXTEMPLATE)
      left = 10
      top = 4.4545
      width = 34
      height = 8.5455
      metric = 0
      text = "Schedule Template"
      colorNormal = "WindowText/BtnFace"
      fontName = "MS Sans Serif"
      fontSize = 8
      pageno = 2
   endwith


   this.BOXASSIGN = new RECTANGLE(this)
   with (this.BOXASSIGN)
      left = 1
      top = 5.4545
      width = 80
      height = 8.5
      metric = 0
      text = "Flight Assignments"
      colorNormal = "WindowText/BtnFace"
      fontName = "MS Sans Serif"
      fontSize = 8
      pageno = 3
   endwith


   this.BUTTONCANCEL = new PUSHBUTTON(this)
   with (this.BUTTONCANCEL)
      onClick = class::BUTTONCANCEL_ONCLICK
      height = 1.1818
      left = 25
      top = 14.75
      width = 12
      text = "Cancel"
      metric = 0
      fontName = "MS Sans Serif"
      fontSize = 8
      group = true
      colorNormal = "BtnText/BtnFace"
      pageno = 0
      value = false
   endwith


   this.BUTTONBACK = new PUSHBUTTON(this)
   with (this.BUTTONBACK)
      onClick = class::BUTTONBACK_ONCLICK
      enabled = false
      height = 1.1818
      left = 39
      top = 14.75
      width = 12
      text = "< &Back"
      metric = 0
      fontName = "MS Sans Serif"
      fontSize = 8
      group = true
      colorNormal = "BtnText/BtnFace"
      pageno = 0
      value = false
   endwith


   this.BUTTONNEXT = new PUSHBUTTON(this)
   with (this.BUTTONNEXT)
      onClick = class::BUTTONNEXT_ONCLICK
      height = 1.1818
      left = 53
      top = 14.75
      width = 12
      text = "&Next >"
      metric = 0
      fontName = "MS Sans Serif"
      fontSize = 8
      group = true
      colorNormal = "BtnText/BtnFace"
      pageno = 0
      value = false
   endwith


   this.BUTTONFINISH = new PUSHBUTTON(this)
   with (this.BUTTONFINISH)
      onClick = class::BUTTONFINISH_ONCLICK
      height = 1.1818
      left = 67
      top = 14.75
      width = 12
      text = "Finish"
      metric = 0
      fontName = "MS Sans Serif"
      fontSize = 8
      group = true
      colorNormal = "BtnText/BtnFace"
      pageno = 0
      value = false
   endwith


   this.BOXLINE = new RECTANGLE(this)
   with (this.BOXLINE)
      left = 1
      top = 14.2273
      width = 80
      height = 0.2
      metric = 0
      text = ""
      colorNormal = "WindowText/BtnFace"
      border = false
      fontName = "MS Sans Serif"
      fontSize = 8
      pageno = 0
      borderStyle = 2
   endwith


   this.SPINBEGIN = new SPINBOX(this)
   with (this.SPINBEGIN)
      height = 1
      left = 52
      top = 6
      width = 13
      metric = 0
      colorHighLight = ""
      rangeMax = 0
      rangeMin = 1
      fontName = "MS Sans Serif"
      fontSize = 8
      value = 1
      validRequired = true
      borderStyle = 7
   endwith


   this.SPINMONTHS = new SPINBOX(this)
   with (this.SPINMONTHS)
      height = 1
      left = 55
      top = 9
      width = 10
      metric = 0
      picture = "99"
      colorHighLight = ""
      rangeMax = 12
      rangeMin = 1
      fontName = "MS Sans Serif"
      fontSize = 8
      value = 1
      validRequired = true
      rangeRequired = true
      borderStyle = 7
   endwith


   this.LABELSTART = new TEXT(this)
   with (this.LABELSTART)
      height = 2
      left = 11
      top = 6
      width = 41
      metric = 0
      colorNormal = "BtnText"
      fontName = "MS Sans Serif"
      fontSize = 8
      text = "What date do you want to use to begin generating schedule information?"
   endwith


   this.LABELMONTHS = new TEXT(this)
   with (this.LABELMONTHS)
      height = 2
      left = 11
      top = 9
      width = 41
      metric = 0
      colorNormal = "BtnText"
      fontName = "MS Sans Serif"
      fontSize = 8
      text = "How many months of schedule information would you like to generate?"
   endwith


   this.LISTTEMPLATE = new LISTBOX(this)
   with (this.LISTTEMPLATE)
      onSelChange = class::LISTTEMPLATE_ONSELCHANGE
      onOpen = class::LISTTEMPLATE_ONOPEN
      height = 7.0909
      left = 11
      top = 5.5
      width = 31
      metric = 0
      id = 110
      fontName = "MS Sans Serif"
      fontSize = 8
      colorHighLight = "HighLightText/HighLight"
      pageno = 2
   endwith


   this.LABELSELECT = new TEXT(this)
   with (this.LABELSELECT)
      height = 1
      left = 36
      top = 6.5
      width = 20
      metric = 0
      colorNormal = "BtnText"
      fontName = "MS Sans Serif"
      fontSize = 8
      text = " Selected:"
      pageno = 3
   endwith


   this.LISTSELECT = new LISTBOX(this)
   with (this.LISTSELECT)
      onSelChange = class::REFRESHDAYS
      height = 6
      left = 36
      top = 7.5
      width = 28
      metric = 0
      id = 115
      fontName = "MS Sans Serif"
      fontSize = 8
      colorHighLight = "HighLightText/HighLight"
      pageno = 3
   endwith


   this.RADIOGEN = new RADIOBUTTON(this)
   with (this.RADIOGEN)
      onChange = class::RADIOCHANGE_ONCHANGE
      transparent = false
      height = 1
      left = 6
      top = 9
      width = 54
      text = "Apply Template Changes to Current Generation Only"
      metric = 0
      colorNormal = "WindowText/BtnFace"
      fontName = "MS Sans Serif"
      fontSize = 8
      group = true
      value = true
      pageno = 4
   endwith


   this.RADIOSAVE = new RADIOBUTTON(this)
   with (this.RADIOSAVE)
      onChange = class::RADIOCHANGE_ONCHANGE
      transparent = false
      height = 1
      left = 6
      top = 10.25
      width = 35
      text = "Save Changes to Selected Template"
      metric = 0
      colorNormal = "WindowText/BtnFace"
      fontName = "MS Sans Serif"
      fontSize = 8
      group = false
      value = false
      pageno = 4
   endwith


   this.RADIONEW = new RADIOBUTTON(this)
   with (this.RADIONEW)
      onChange = class::RADIOCHANGE_ONCHANGE
      transparent = false
      height = 1
      left = 6
      top = 11.5
      width = 25
      text = "Save as New Template"
      metric = 0
      colorNormal = "WindowText/BtnFace"
      fontName = "MS Sans Serif"
      fontSize = 8
      group = false
      value = false
      pageno = 4
   endwith


   this.CHECKSUNDAY = new CHECKBOX(this)
   with (this.CHECKSUNDAY)
      enabled = false
      transparent = false
      height = 1
      left = 65
      top = 6.5
      width = 14
      text = "Sunday"
      metric = 0
      colorNormal = "WindowText/BtnFace"
      fontName = "MS Sans Serif"
      fontSize = 8
      value = false
      group = true
      pageno = 3
   endwith


   this.CHECKMONDAY = new CHECKBOX(this)
   with (this.CHECKMONDAY)
      enabled = false
      transparent = false
      height = 1
      left = 65
      top = 7.5
      width = 14
      text = "Monday"
      metric = 0
      colorNormal = "WindowText/BtnFace"
      fontName = "MS Sans Serif"
      fontSize = 8
      value = false
      group = true
      pageno = 3
   endwith


   this.CHECKTUESDAY = new CHECKBOX(this)
   with (this.CHECKTUESDAY)
      enabled = false
      transparent = false
      height = 1
      left = 65
      top = 8.5
      width = 14
      text = "Tuesday"
      metric = 0
      colorNormal = "WindowText/BtnFace"
      fontName = "MS Sans Serif"
      fontSize = 8
      value = false
      group = true
      pageno = 3
   endwith


   this.CHECKWEDNESDAY = new CHECKBOX(this)
   with (this.CHECKWEDNESDAY)
      enabled = false
      transparent = false
      height = 1
      left = 65
      top = 9.5
      width = 14
      text = "Wednesday"
      metric = 0
      colorNormal = "WindowText/BtnFace"
      fontName = "MS Sans Serif"
      fontSize = 8
      value = false
      group = true
      pageno = 3
   endwith


   this.CHECKTHURSDAY = new CHECKBOX(this)
   with (this.CHECKTHURSDAY)
      enabled = false
      transparent = false
      height = 1
      left = 65
      top = 10.5
      width = 14
      text = "Thursday"
      metric = 0
      colorNormal = "WindowText/BtnFace"
      fontName = "MS Sans Serif"
      fontSize = 8
      value = false
      group = true
      pageno = 3
   endwith


   this.CHECKFRIDAY = new CHECKBOX(this)
   with (this.CHECKFRIDAY)
      enabled = false
      transparent = false
      height = 1
      left = 65
      top = 11.5
      width = 14
      text = "Friday"
      metric = 0
      colorNormal = "WindowText/BtnFace"
      fontName = "MS Sans Serif"
      fontSize = 8
      value = false
      group = true
      pageno = 3
   endwith


   this.CHECKSATURDAY = new CHECKBOX(this)
   with (this.CHECKSATURDAY)
      enabled = false
      transparent = false
      height = 1
      left = 65
      top = 12.5
      width = 14
      text = "Saturday"
      metric = 0
      colorNormal = "WindowText/BtnFace"
      fontName = "MS Sans Serif"
      fontSize = 8
      value = false
      group = true
      pageno = 3
   endwith


   this.HELPSTEP4 = new TEXT(this)
   with (this.HELPSTEP4)
      height = 3
      left = 13
      top = 5
      width = 65
      metric = 0
      colorNormal = "BtnText"
      fontName = "MS Sans Serif"
      fontSize = 8
      text = "That's all the information the wizard needs to generate schedule information. Click on Finish to begin the generation."
      pageno = 5
   endwith


   this.REDARROW1 = new IMAGE(this)
   with (this.REDARROW1)
      height = 0.6316
      left = 7
      top = 6
      width = 1.8333
      metric = 0
      dataSource = 'FILENAME "redarrow.gif"'
      alignment = 3
      borderStyle = 3
   endwith


   this.IMAGEWAND = new IMAGE(this)
   with (this.IMAGEWAND)
      height = 3
      left = 1.5
      top = 0.8
      width = 10.1667
      metric = 0
      dataSource = 'FILENAME "wand.gif"'
      alignment = 3
      borderStyle = 3
   endwith


   this.HELPSTEP1 = new TEXT(this)
   with (this.HELPSTEP1)
      height = 2.5
      left = 12
      top = 0.75
      width = 65
      metric = 0
      colorNormal = "BtnText"
      fontName = "MS Sans Serif"
      fontSize = 8
      text = "The Schedule Generation Wizard can generate future schedule information based on schedule templates. After generating a schedule, you can modify it from the Fleet Tree and Schedule forms."
   endwith


   this.REDARROW2 = new IMAGE(this)
   with (this.REDARROW2)
      height = 0.6316
      left = 7
      top = 9
      width = 1.8333
      metric = 0
      dataSource = 'FILENAME "redarrow.gif"'
      alignment = 3
      borderStyle = 3
   endwith


   this.REDARROW3 = new IMAGE(this)
   with (this.REDARROW3)
      height = 0.6316
      left = 4
      top = 0.8
      width = 1.8333
      metric = 0
      dataSource = 'FILENAME "redarrow.gif"'
      alignment = 3
      pageno = 2
      borderStyle = 3
   endwith


   this.HELPSTEP2 = new TEXT(this)
   with (this.HELPSTEP2)
      height = 2.5789
      left = 7
      top = 0.7368
      width = 70
      metric = 0
      colorNormal = "BtnText"
      fontName = "MS Sans Serif"
      fontSize = 8
      text = "Select a schedule template. Each schedule template contains aircraft flight assignments based on the days of the week. You can rename or delete any template except the Standard template."
      pageno = 2
   endwith


   this.REDARROW4 = new IMAGE(this)
   with (this.REDARROW4)
      height = 0.6316
      left = 4
      top = 0.8
      width = 1.8333
      metric = 0
      dataSource = 'FILENAME "redarrow.gif"'
      alignment = 3
      pageno = 3
      borderStyle = 3
   endwith


   this.IMAGEBOLT = new IMAGE(this)
   with (this.IMAGEBOLT)
      height = 3.0526
      left = 1.5
      top = 5
      width = 10.1667
      metric = 0
      dataSource = 'FILENAME "bigbolt.gif"'
      alignment = 3
      pageno = 5
      borderStyle = 3
   endwith


   this.LISTAVAIL = new LISTBOX(this)
   with (this.LISTAVAIL)
      height = 6
      left = 3
      top = 7.5
      width = 28
      metric = 0
      id = 139
      fontName = "MS Sans Serif"
      fontSize = 8
      colorHighLight = "HighLightText/HighLight"
      pageno = 3
   endwith


   this.BUTTONSELECT = new PUSHBUTTON(this)
   with (this.BUTTONSELECT)
      onClick = class::BUTTONSELECT_ONCLICK
      height = 1.2273
      left = 31.5
      top = 9
      width = 4
      text = ">"
      metric = 0
      fontName = "MS Sans Serif"
      fontSize = 8
      group = true
      colorNormal = "BtnText/BtnFace"
      pageno = 3
      value = false
   endwith


   this.BUTTONREMOVE = new PUSHBUTTON(this)
   with (this.BUTTONREMOVE)
      onClick = class::BUTTONREMOVE_ONCLICK
      height = 1.1818
      left = 31.5
      top = 10.5
      width = 4
      text = "<"
      metric = 0
      fontName = "MS Sans Serif"
      fontSize = 8
      group = true
      colorNormal = "BtnText/BtnFace"
      pageno = 3
      value = false
   endwith


   this.LABELAVAIL = new TEXT(this)
   with (this.LABELAVAIL)
      height = 1
      left = 3
      top = 6.5
      width = 20
      metric = 0
      colorNormal = "BtnText"
      fontName = "MS Sans Serif"
      fontSize = 8
      text = " Available:"
      pageno = 3
   endwith


   this.LABELCRAFT = new TEXT(this)
   with (this.LABELCRAFT)
      height = 1
      left = 3
      top = 4
      width = 8
      metric = 0
      colorNormal = "BtnText"
      alignVertical = 1
      fontName = "MS Sans Serif"
      fontSize = 8
      text = "Aircraft:"
      pageno = 3
   endwith


   this.COMBOAIRCRAFT = new COMBOBOX(this)
   with (this.COMBOAIRCRAFT)
      onChange = class::REFRESHFLIGHTLISTS
      height = 1.1
      left = 12
      top = 4
      width = 30
      metric = 0
      fontName = "MS Sans Serif"
      fontSize = 8
      pageno = 3
      style = 2
   endwith


   this.HELPSTEP3 = new TEXT(this)
   with (this.HELPSTEP3)
      height = 3
      left = 7
      top = 0.75
      width = 70
      metric = 0
      colorNormal = "BtnText"
      fontName = "MS Sans Serif"
      fontSize = 8
      text = "You can modify the template by selecting and removing flight assignments for each aircraft. For each flight assignment, you can select what days of the week to schedule for a selected aircraft. The Flight table determines what days are available for each f";
       + "light."
      pageno = 3
   endwith


   this.BUTTONDELETE = new PUSHBUTTON(this)
   with (this.BUTTONDELETE)
      onClick = class::BUTTONDELETE_ONCLICK
      enabled = false
      height = 1.18
      left = 50
      top = 6.6316
      width = 15
      text = "Delete..."
      metric = 0
      fontName = "MS Sans Serif"
      fontSize = 8
      group = true
      colorNormal = "BtnText/BtnFace"
      pageno = 2
      value = false
   endwith


   this.BUTTONRENAME = new PUSHBUTTON(this)
   with (this.BUTTONRENAME)
      onClick = class::BUTTONRENAME_ONCLICK
      enabled = false
      height = 1.18
      left = 50
      top = 8.5263
      width = 15
      text = "Rename..."
      metric = 0
      fontName = "MS Sans Serif"
      fontSize = 8
      group = true
      colorNormal = "BtnText/BtnFace"
      pageno = 2
      value = false
   endwith


   this.ENTRYTNAME = new ENTRYFIELD(this)
   with (this.ENTRYTNAME)
      enabled = false
      height = 1
      left = 52
      top = 11.5
      width = 24
      metric = 0
      colorHighLight = ""
      fontName = "MS Sans Serif"
      fontSize = 8
      value = "NEWTEMPLATE"
      pageno = 4
      borderStyle = 7
   endwith


   this.ELABELNEW = new ENTRYFIELD(this)
   with (this.ELABELNEW)
      when = {||false}
      enabled = false
      height = 1
      left = 41
      top = 11.65
      width = 9.5
      metric = 0
      colorNormal = "BtnText/BtnFace"
      colorHighLight = ""
      border = false
      tabStop = false
      fontName = "MS Sans Serif"
      fontSize = 8
      value = "Template:"
      pageno = 4
      borderStyle = 3
   endwith


   this.IMAGE1 = new IMAGE(this)
   with (this.IMAGE1)
      height = 0.6316
      left = 4
      top = 0.8
      width = 1.8333
      metric = 0
      dataSource = 'FILENAME "redarrow.gif"'
      alignment = 3
      pageno = 4
      borderStyle = 3
   endwith


   this.TEXT1 = new TEXT(this)
   with (this.TEXT1)
      height = 3.5263
      left = 7
      top = 0.7368
      width = 72
      metric = 0
      colorNormal = "BtnText"
      fontName = "MS Sans Serif"
      fontSize = 8
      text = "If you made any changes to the template, you can now choose to use the changes for the current generation only, save changes to the current template or create a new template. To create a new template without generating altering the schedule table, uncheck ";
       + "the Add option and select Save as New Template ."
      pageno = 4
   endwith


   this.CHECKGEN = new CHECKBOX(this)
   with (this.CHECKGEN)
      transparent = false
      height = 1
      left = 7
      top = 5.6842
      width = 51
      text = "Add Generated Rows to the Schedule Table"
      metric = 0
      colorNormal = "WindowText/BtnFace"
      fontName = "MS Sans Serif"
      fontSize = 8
      value = true
      group = true
      pageno = 4
   endwith


   this.rowset = this.schedule1.rowset

   // {Linked Method} form.buttonselect.onClick
   function BUTTONSELECT_onClick
       class::moveItem( this.form.listAvail, this.form.listSelect )
       this.form.qGen.rowset.beginAppend()
       with ( this.form.qGen.rowset )
           fields["Template Name"].value := this.form.listTemplate.value
           fields["Aircraft ID"].value   := INT( VAL( this.form.comboAircraft.value ) )
           fields["Flight ID"].value     := INT( VAL( this.form.listSelect.value ) )
       endwith
       this.form.qGen.rowset.save()
   return ( class::refreshDays() )

   // {Linked Method} form.buttonremove.onClick
   function BUTTONREMOVE_onClick
      local bFound, nFlight
      nFlight = INT( VAL( this.form.listSelect.value ) )
      class::moveItem( this.form.listSelect, this.form.listAvail )
      bFound = this.form.qGen.rowset.applyLocate( ;
            '"Template Name" = ' + "'" + this.form.listTemplate.value + "'" +  ;
      ' AND "Aircraft ID" = '  + INT( VAL(this.form.comboAircraft.value) ) + ;
      ' AND "Flight ID" = '    + INT( nFlight ) )
      if ( bFound )
         this.form.qGen.rowset.delete()
         if ( not this.form.qGen.rowset.next(-1) )
            this.form.qGen.rowset.next()
         endif
      endif
      class::refreshDays()
   return ( bFound )

   // {Linked Method} form.buttonrename.onClick
   function BUTTONRENAME_onClick
      local sName
      sName = this.form.listTemplate.value
      sName := prompt("New name:", sName )
      if ( sName <> this.form.listTemplate.value )
         class::renameTemplate( sName, "genwizard.dbf" )
         class::renameTemplate( sName )
         class::fillTemplateList( this.form, sName )
      endif
   return

   function renameTemplate( sNewName, pTable )
      local tQ, sOldName, sTable
      tQ = new Query()
      sOldName = this.form.listTemplate.value
      if ( PCOUNT() == 1 )
         sTable = "'" + this.form.gTable + "'"
      else
         sTable = "'" + LTRIM(RTRIM(pTable)) + "'"
      endif
      with ( tQ )
         database := this.form.dmConnect.ref.dbFleet
         sql := "SELECT * FROM " + sTable
         active := true
      endwith
      do while ( tQ.rowset.applyLocate('"Template Name" = ' + "'" + sOldName + "'" ) )
         tQ.rowset.fields["Template Name"].value := sNewName
      enddo
      tQ.active := false
   return ( sTable )

   function moveItem( listFrom, listTo )
      local bSelectOK, nIndex
      bSelectOK = ( listFrom.curSel > 0 )
      if ( bSelectOK )
         listTo.options.add( listFrom.value )
         listTo.options.sort()
         nIndex = listTo.options.scan( listFrom.value )
         listFrom.options.delete( listFrom.curSel )
         if ( listFrom.options.size > 1 )
            listFrom.options.resize( listFrom.options.size - 1 )
            if ( listFrom.options.size < listFrom.curSel )
               listFrom.curSel := listFrom.options.size
            endif
         else
            listFrom.options = new Array()
         endif
         listFrom.dataSource := listFrom.dataSource
         listTo.dataSource   := listTo.dataSource
         listTo.curSel       := nIndex
      endif
   return ( bSelectOK )


   // {Linked Method} form.radionew.onChange
   // {Linked Method} form.radiosave.onChange
   // {Linked Method} form.radiogen.onChange
   function RADIOCHANGE_onChange
      local bNew
      bNew = this.form.radioNew.value
      with (this.form)
         eLabelNew.enabled  := bNew
         entryTName.enabled := bNew
      endwith
      if ( bNew )
         this.form.entryTname.value := "NEWTEMPLATE"
      else
         this.form.entryTName.value := this.form.listTemplate.value
      endif
   return

   // {Linked Method} form.buttonback.onClick
   function BUTTONBACK_onClick
      this.form.pageno--
      this.enabled :=  ( this.form.pageno > 1 )
      this.form.buttonNext.enabled := ( this.form.pageno < 5 )
      class::updateCaption()
   return ( this.form.pageno )

   function updateCaption
      this.form.text = "Schedule Generation Wizard - Step " + ;
         LTRIM( RTRIM ( STR( this.form.pageno ) ) ) + " of 5 "
   return ( this.form.text )

   // {Linked Method} form.buttoncancel.onClick
   function BUTTONCANCEL_onClick
   return ( this.form.close() )

   // {Linked Method} form.buttondelete.onClick
   function BUTTONDELETE_onClick
      local bDelete
      bDelete = MSGBOX("You are about to delete the selected template." ;
                     + CHR(13) ;
                     + "Click Yes to delete the current template.", ;
                     "Alert", ;
                     4) == 6
      if ( bDelete )
         // delete template from genwizard and working copy
         class::deleteTemplate()  // default is working copy
         class::deleteTemplate("genwizard.dbf")
         class::fillTemplateList( this.form )
      endif
   return ( bDelete )

   function deleteTemplate( pTable )
      local tQ, sTable
      tQ = new Query()
      if ( PCOUNT() == 0 )
         sTable = "'" + this.form.gTable + "'"
      else
         sTable = "'" + LTRIM(RTRIM(pTable)) + "'"
      endif
      with ( tQ )
         database := this.form.dmConnect.ref.dbFleet
         sql      := 'SELECT * FROM ' + sTable
         active := true
      endwith
      tQ.rowset.filter := '"Template Name" = ' + ;
                 "'" + this.form.listTemplate.value + "'"
      tQ.rowset.first()
      do while ( not tQ.rowset.endOfSet )
         tQ.rowset.delete()
         tQ.rowset.first()
      enddo
      tQ.active := false
      if ( PCOUNT() == 1 )
         this.form.dmConnect.ref.dbFleet.packTable( pTable )
      endif
   return ( sTable )

   // {Linked Method} form.buttonfinish.onClick
   function BUTTONFINISH_onClick
      local bFinish, nCount, sMessage
      bFinish  = true
      nCount   = 0
      sMessage = "Operation Complete." + CHR(13) + CHR(13)
      do case
         case ( this.form.radioNew.value )
              if ( class::ValidateNewName() )
                 bFinish := true
                 class::saveTemplate( true )
                 sMessage += "Saved new template as: " + ;
                             this.form.entryTname.value + CHR(13) + CHR(13)
              endif
         case ( this.form.radioSave.value )
              class::deleteTemplate("genwizard.dbf")
              class::saveTemplate( false )
              sMessage += "Saved changes to template: " + ;
                      this.form.listTemplate.value + CHR(13) + CHR(13)
      endcase
      if ( bFinish )
         if ( this.form.checkGen.value )
            nCount = class::generateSchedule()
            sMessage += LTRIM(RTRIM(STR(nCount))) + ;
                      " entries added to the Schedule table." + CHR(13)
         endif
         MSGBOX( sMessage, "Schedule Generation Wizard", 64 )
         this.form.close()
      else
         this.form.pageno := 4
      endif
   return ( bFinish )

   // {Linked Method} form.buttonnext.onClick
   function BUTTONNEXT_onClick
      local bNext
      bNext = true
      if ( this.form.pageno == 3 )
         class::RADIOCHANGE_onChange()
      endif
      if ( ( this.form.pageno == 4 ) and this.form.radioNew.value )
         bNext := class::ValidateNewName()
      endif
      if ( bNext )
         this.form.pageno++
         this.form.buttonBack.enabled :=  ( this.form.pageno > 1 )
         this.enabled := ( this.form.pageno < 5 )
         class::updateCaption()
         if ( this.form.pageno == 3 )
            class::refreshFlightLists()
         endif
      endif
   return ( this.form.pageno )


   // {Linked Method} form.open
   function Form_Open
      // force modal
   return class::Form_ReadModal()

   // {Linked Method} form.onClose
   function Form_onClose
      this.qGen.active := false
   return ( this.dmConnect.ref.dbFleet.dropTable( this.gTable ) )

   // {Linked Method} form.readModal
   function Form_ReadModal
      local lastDate, q, i
      q = new Query()
      i = 1

      // Copy templates to temporary table. Use temporary table
      // as the datalink to the day of the week checkbox group.
      this.gTable = FUNIQUE() +".DBF"
      this.DMConnect.ref.dbFleet.copyTable("GENWIZARD.DBF", this.gTable )
      this.qGen = new Query()
      with ( this.qGen )
         database := this.DMConnect.ref.dbFleet
         sql      := "SELECT * FROM '" + this.gTable + "'"
         active   := true
      endwith
      with ( this )
         checkSunday.dataLink    := this.qGen.rowset.fields["SUNDAY"]
         checkMonday.dataLink    := this.qGen.rowset.fields["MONDAY"]
         checkTuesday.dataLink   := this.qGen.rowset.fields["TUESDAY"]
         checkWednesday.dataLink := this.qGen.rowset.fields["WEDNESDAY"]
         checkThursday.dataLink  := this.qGen.rowset.fields["THURSDAY"]
         checkFriday.dataLink    := this.qGen.rowset.fields["FRIDAY"]
         checkSaturday.dataLink  := this.qGen.rowset.fields["SATURDAY"]
      endwith

      // calculate generation start date
      with ( q )
         database := this.DMConnect.ref.dbFleet
         sql      := 'SELECT MAX(schedule."Flight Date") FROM schedule'
         active   := true
      endwith
      lastDate = q.rowset.fields[1].value
      q.active := false

      with ( this.spinBegin )
         value        := lastDate + 1
         minRange     := lastDate
         maxRange     := lastDate.setYear( lastDate.getYear() + 2 )
         rangeRequire := true
      endwith

      class::fillTemplateList(this)

      // fill aircraft combobox
      i := 1
      with ( q )
         sql    := 'SELECT aircraft."Aircraft ID", make, model ' + ;
                   ' FROM aircraft ' + ;
                   ' ORDER BY aircraft."Aircraft ID"'
         active := true
      endwith

      this.comboAircraft.options = new Array( q.rowset.count() )
      do while ( not q.rowset.endOfSet )
         this.comboAircraft.options[i] := " " + ;
           RTRIM( LTRIM( STR( INT( q.rowset.fields["Aircraft ID"].value ) ) ) ) ;
           + " - " + q.rowset.fields["Make"].value.rightTrim() + " " + ;
                     q.rowset.fields["Model"].value.rightTrim()

         i++
         q.rowset.next()
      enddo
      q.active := false

      with ( this.comboAircraft )
         dataSource := "ARRAY FORM.comboAircraft.options"
         value := this.comboAircraft.options[1]
      endwith

      this.pageno := 1
      this.mdi := false
   return GENWIZARDFORM::ReadModal()

   function fillTemplateList( thisForm, sTemplate )
      // fill template listbox
      local i, nSelect, q, tList

      i       = 1
      nSelect = 1
      q       = new Query()
      tList   = thisForm.listTemplate

      sTemplate = IIF( PCOUNT() > 1, sTemplate, "Standard" )

      q.sql := 'SELECT DISTINCT gwizard."Template Name" ' + ;
               ' FROM "' + thisForm.gTable + '" gwizard ' + ;
               ' ORDER BY gwizard."Template Name"'
      q.active := true

      tList.options = new Array( q.rowset.count() )
      do while ( not q.rowset.endOfSet )
         tList.options[i] := q.rowset.fields[1].value
         if ( q.rowset.fields[1].value.rightTrim() == sTemplate.rightTrim() )
            nSelect := i
         endif
         i++
         q.rowset.next()
      enddo
      q.active := false

      tList.dataSource := "ARRAY FORM.listTemplate.options"
      if ( PCOUNT() > 1 )
         tList.curSel := nSelect
      endif

      with ( thisForm )
         buttonDelete.enabled := sTemplate <> "Standard"
         buttonRename.enabled := sTemplate <> "Standard"
      endwith
   return ( nSelect )

   // {Linked Method} form.listselect.onSelChange
   function refreshDays
      local rFlight, nFlight, bSelect
      rGen = this.form.qGen.rowset
      rFlight = this.form.flight1.rowset
      nFlight = VAL( this.form.listSelect.value )
      bSelect = ( this.form.listSelect.cursel < 1 )

      if ( bSelect )
         with ( this.form )
            checkSunday.enabled    := false
            checkMonday.enabled    := false
            checkTuesday.enabled   := false
            checkWednesday.enabled := false
            checkThursday.enabled  := false
            checkFriday.enabled    := false
            checkSaturday.enabled  := false
         endwith
      else
         if ( rFlight.applyLocate( '"Flight ID" = ' + INT( nFlight ) ) )
            rGen.save()
            if ( class::locateGenRow() )
               with ( this.form )
                  checkSunday.enabled    := rFlight.fields["SUNDAY"].value
                  checkMonday.enabled    := rFlight.fields["MONDAY"].value
                  checkTuesday.enabled   := rFlight.fields["TUESDAY"].value
                  checkWednesday.enabled := rFlight.fields["WEDNESDAY"].value
                  checkThursday.enabled  := rFlight.fields["THURSDAY"].value
                  checkFriday.enabled    := rFlight.fields["FRIDAY"].value
                  checkSaturday.enabled  := rFlight.fields["SATURDAY"].value
               endwith
            endif
         endif
      endif
   return ( bSelect )

   // {Linked Method} form.comboaircraft.onChange
   function refreshFlightLists
       local q, rFlight, nFlight, sFlight
       q = new Query()
       rFlight = this.form.flight1.rowset
       with ( q )
          database := this.form.DMConnect.ref.dbFleet
          sql := 'SELECT genwizard."Flight ID", ' + ;
                 '       flight."From ID", ' + ;
                 '       flight."To ID" ' + ;
            ' FROM "' + this.form.gTable +'" genwizard ' + ;
            ' INNER JOIN "flight.dbf" flight ' + ;
            '    ON (genwizard."Flight ID" = flight."Flight ID") ' + ;
            ' WHERE (genwizard."Template Name" = ' + "'" +  this.form.listTemplate.value + "')" +;
            '   AND (genwizard."Aircraft ID" = ' + INT( VAL( this.form.comboAircraft.value ) ) + ")" + ;
            ' ORDER BY genwizard."Flight ID" '
          active := true
       endwith

       this.form.listAvail.options  = new Array()
       this.form.listSelect.options = new Array()

       rFlight.first()
       do while ( not rFlight.endOfSet )
          nFlight = INT( rFlight.fields["Flight ID"].value )
          sFlight = " " + TRANSFORM(nFlight,"99") + " - " + ;
                    rFlight.fields["From ID"].value + " to " + ;
                    rFlight.fields["To ID"].value + "   " + ;
                    rFlight.fields["Departs"].value
          if ( q.rowset.endOfSet )
             this.form.listAvail.options.add( sFlight )
          else
             if ( nFlight == INT( q.rowset.fields["Flight ID"].value ) )
                this.form.listSelect.options.add( sFlight )
                q.rowset.next()
             else
                this.form.listAvail.options.add( sFlight )
             endif
          endif
          rFlight.next()
       enddo
       q.active := false
       this.form.listAvail.options.sort()
       with ( this.form.listAvail )
          dataSource := "ARRAY FORM.listAvail.options"
          curSel := 1
       endwith
       this.form.listSelect.dataSource := "ARRAY FORM.listSelect.options"
       if ( this.form.listSelect.options.size > 0 )
          this.form.listSelect.curSel := 1
       endif

       class::locateGenRow()
       class::refreshDays()
   return

   function locateGenRow
      local rGen, sTemplate, nFlight, nAircraft, bFound
      rGen = this.form.qGen.rowset
      sTemplate = "'" + this.form.listTemplate.value + "'"
      nFlight   = INT( VAL( this.form.listSelect.value ) )
      nAircraft = INT( VAL( this.form.comboAircraft.value ) )
      bFound = rGen.applyLocate('("Template Name" = ' + sTemplate + ")" + ;
                           ' AND ("Aircraft ID" = ' + nAircraft + ")" + ;
                           ' AND ("Flight ID" = ' + nFlight   + ")")
   return (bFound)

   function saveTemplate( bNew )
      local db, qSource, qDest, uSet, sTemp, bRVal
      qSource = new Query()
      qDest   = new Query()
      uSet    = new UpdateSet()
      sTemp   = "T" + RIGHT(FUNIQUE(),7) + ".DBF"
      bRVal   = true
      db = this.form.dmConnect.ref.dbFleet
      db.copyTable( this.form.gTable, sTemp )
      db.executeSQL('DELETE FROM "' + sTemp + '"  gwizard ' + ;
                    ' WHERE gwizard."Template Name" <> ' + ;
                      "'" + this.form.listTemplate.value + "'")
      db.packTable( sTemp )
      with ( qSource )
         database := db
         sql      := "SELECT * FROM '" + sTemp + "'"
         active   := true
      endwith
      if ( bNew )
         do while ( not qSource.rowset.endOfSet )
            qSource.rowset.fields["Template Name"].value := ;
                 this.form.entryTname.value
            qSource.rowset.next()
         enddo
         qSource.rowset.first()
      endif
      with ( qDest )
         database := db
         sql      := "SELECT * FROM 'GENWIZARD.DBF'"
         active   := true
      endwith

      with ( uSet )
         source      := qSource.rowset
         destination := qDest.rowset
      endwith
      bRVal := uSet.append()
      qSource.active := false
      qDest.active := false
   return ( bRVal )

   function generateSchedule
      local nCount, dateCursor, dateStop, dateStart
      local rSched, tQ, tF
      nCount     = 0
      dateStart  = this.form.spinBegin.value
      dateCursor = new Date()
      dateStop   = new Date()
      rSched     = this.form.schedule1.rowset
      tQ         = new Query()

      with ( tQ )
          sql := 'SELECT * ' + ;
                 ' FROM "' + this.form.gTable + '" gwizard ' + ;
                 ' WHERE gwizard."Template Name" = ' + ;
                    "'" + this.form.listTemplate.value + "'"
          active := true
      endwith
      tF = tQ.rowset.fields

      dateStop.setDate( dateStart.getDate() )
      dateStop.setMonth( dateStart.getMonth() + 1 )
      dateStop.setYear( dateStart.getYear() )

      do while ( not tQ.rowset.endOfSet )

         dateCursor.setDate( dateStart.getDate() )
         dateCursor.setMonth( dateStart.getMonth() )
         dateCursor.setYear( dateStart.getYear() )
         do while ( VAL( DTOS( dateCursor ) ) < VAL( DTOS( dateStop) ) )
         if ( tF[ CDOW( dateCursor ) ].value )
               rSched.beginAppend()
               rSched.fields["Flight Date"].value := dateCursor
               rSched.fields["Flight ID"].value   := tF["Flight ID"].value
               rSched.fields["Aircraft ID"].value := tF["Aircraft ID"].value
               rSched.save()
               nCount++
            endif
            dateCursor.setDate( dateCursor.getDate() + 1 )
         enddo
         tQ.rowset.next()
      enddo

   return ( nCount )

   // {Linked Method} form.listtemplate.onOpen
   function LISTTEMPLATE_onOpen
      if ( this.options.size > 0 )
         this.curSel := 1
      endif
      with ( this.form )
           buttonDelete.enabled := this.options[1] <> "Standard"
           buttonRename.enabled := this.options[1] <> "Standard"
      endwith
   return ( this.cursel )


   // {Linked Method} form.listtemplate.onSelChange
   function LISTTEMPLATE_onSelChange
      local bStandard
      bStandard = (LTRIM(this.value) == "Standard")
      this.form.buttonDelete.enabled := ( not bStandard )
      this.form.buttonRename.enabled := ( not bStandard )
   return (bStandard)

   function ValidateNewName
      local bValid
      bValid = false
      if ISBLANK(this.form.entryTName.value)
         MSGBOX("New Template name cannot be blank.","Alert",0 + 48)
      else
         q = new Query()
         with ( q )
            database := this.form.dmConnect.ref.dbFleet
            sql      := 'select count(gwizard."Template Name") ' + ;
                        ' from genwizard gwizard ' + ;
                        ' where gwizard."Template Name" = ' + ;
                    "'" + this.form.entryTName.value + "'"
            active   := true
         endwith
         if ( q.rowset.fields[1].value == 0 )
            bValid := true
         else
            MSGBOX("New template name must be unique.","Alert",0 + 48)
         endif
         q.active := false
      endif
   return bValid
endclass

function prompt( sCaption, sValue )
   local sNewValue, f
   sNewValue = sValue
   f = new promptForm()
   f.textCaption.text := sCaption
   f.entry.value := sValue
   f.readModal()
   if ( f.OK )
      sNewValue := f.entry.value
   endif
   f.release()
return (sNewValue)

class promptForm of FORM
   with (this)
      onOpen = { ; this.OK = false }
      scaleFontBold = false
      height = 6
      left = 29
      top = 6
      width = 53
      text = ""
      mdi = false
   endwith


   this.ENTRY = new ENTRYFIELD(this)
   with (this.ENTRY)
      height = 1
      left = 2.5
      top = 3
      width = 49
      fontSize = 8
      borderStyle = 7
   endwith


   this.TEXTCAPTION = new TEXT(this)
   with (this.TEXTCAPTION)
      height = 2
      left = 2.5
      top = 0.5
      width = 49
      colorNormal = "BtnText"
      fontSize = 8
      text = "Prompt"
   endwith


   this.BUTTONOK = new PUSHBUTTON(this)
   with (this.BUTTONOK)
      onClick = { ; this.form.OK := true ; this.form.close() }
      height = 1.15
      left = 28
      top = 4.5
      width = 10.5
      text = "OK"
      default = true
      fontSize = 8
      group = true
   endwith


   this.BUTTONCANCEL = new PUSHBUTTON(this)
   with (this.BUTTONCANCEL)
      onClick = { ; this.form.close() }
      height = 1.15
      left = 41
      top = 4.5
      width = 10.5
      text = "Cancel"
      fontSize = 8
      group = true
   endwith

endclass